Recordari
Recordari, Recollect, Recount, Recognoscere - in so many different ways
List of "plug compatible USB cameras" for use with QuickTime Player 10.0. This means tried, tested and passed with no extra software, no extra drivers, plug-in and go!
- Epson ELPDC06 visualiser, document camera (up to 1600 x 1200)
- Jaycar Electronics Digitech QC3233 , USB 2.0 (up to 1600 x 1200)
I was recently fortunate to gain a little experience in using an EPSON ELPDC06 document imager. For the short time I was able to use the device, I found it really simple to use and set up. It folds away into a very neat bundle, inside a soft case, with the imaging sensor (camera) very well protected. It has software for a Macintosh but I was interested in seeing how it could be used with other Macintosh software, in particular video applications like QuickTime Player 10 that has inbuilt video recording capabilities.
Two words of warning. Make sure if you decide to acquire this device that the device you are purchasing has a Serial No beginning with "N2JF" et. seq. - These are Macintosh compatible and come with Mac software. A second caveat is that the device seems somewhat expensive for what it does. Perhaps by shopping around you can find a good deal. But it's like a Mac, expensive but very well designed and eminently useable. The device is sturdy and only requires a USB cable to connect to the computer. All power to it pass through the USB cable. A long USB cable is supplied.
Without using the specialised software that comes with it:
- It has two white LEDs that can be turned on either remotely or using a button on the base.
- It will auto focus by pressing a button on the base
- it will freeze an image while being displayed by pressing a button on the base
- it appears as a USB streaming (isochronous) camera to the Mac.
- It is very ergonomically designed. The whole device easily folds up into a robust package 260 mm x 76 mm by 60 mm within seconds weighing in at 0.9 kg with no protruding bits and is very easy to deploy within seconds.
There is obviously a great deal of potential for using this device especially in places where you want to augment your digital presentations. For example using an application called PiP (Picture in Picture), you can overlay a live video stream on top of your Keynote presentation. It is not "attached" to the presentation but PiP's window can be moved around and mouse pointer moved over it while Keynote is live. PiP cannot record the video it is displaying.
I also found that the application FrameByFrame will accept video from the ELPDC06 for stop motion recording. The device would be ideal for science lessons where you wanted to show closeup images of science demonstrations or for students to record their science experiments. Yes, you could go for an elaborate digital camera and tripod and flood lighting arrangement, but the ELPDC06 is much tidier and much less hassle.
QTPlayer 10 can record the video only stream as a file for later replay but interestingly you can integrate any audio stream from the built-in ports while recording the video. It can stream video at 640 x 480 (millions of colours) at about 12 fps and you can capture video of 1600 x 1200 (millions of colours) at about 3 to 4 fps. The data rate for this HD stream is about 8 Mb/s!
If you want to effectively use QTP 10 and Keynote, you will have arrange them side by side once QTP 10 starts up. As an example of what could be done to manage using the ELPDC06 without using the specialised software that comes with the device, here is a very basic control script in AppleScript.
-- Ver. 1.1 - Drive Epson ELPD06 document camera
-- Ian Parker first worked on 2010-10-01, last worked on 2010-10-04
-- Mac OS X 10.6.4, nearly all functionality derived from QT Player 10
-- can manage basic recording from any Mac enabled USB/Firewire camera
-- movie recording control script for use by science teachers
-- use up arrow(go) and down arrow(pause) keys for stop-motion recordings
-- requires Extra Suites for key press recognition
--
set {today, save_folder} to {current date, (path to desktop as string)}
set dateString to (year of today & "-" & (month of today as number) & "-" & day of today) as string
set {key_pressed, alert_message} to {"", "Please connect ELPD06 document camera"}
tell application "QuickTime Player" to set connected_camera_list to name of every video recording device
if "ELPDC06" is in connected_camera_list then
display alert "Press spacebar to start" as warning buttons {"OK"} default button 1
repeat until key_pressed is in {"s", "space"}
tell application "Extra Suites" to set key_pressed to (ES keys down) as string
end repeat
tell application "QuickTime Player"
activate
set recording_document to new movie recording
start recording_document
end tell
repeat
tell application "Extra Suites" to set key_pressed to (ES keys down) as string
if key_pressed is in {"s", "space"} then exit repeat
tell application "QuickTime Player"
if key_pressed is in {"p", "down arrow"} then pause recording_document
if key_pressed is in {"r", "up arrow"} then resume recording_document
end tell
end repeat
tell application "QuickTime Player"
try
resume recording_document
end try
stop recording_document
end tell
tell application "Finder"
try
set name of file (save_folder & "Movie Recording.mov") to "ELPDC06Video-" & dateString & ".mov"
update save_folder
end try
end tell
tell application "QuickTime Player" to quit
else -- there's no point continuing so ...
say alert_message
display alert alert_message as warning buttons {"OK"} default button 1
end if
Time Lapse Video Recording
If you connect a Mac enabled video camera (either via Firewire or USB) you can do time lapse video recording very easily without any additional equipment. This proof of concept AppleScript will allow you to set:
- off-interval of capture (seconds)
- on-interval of capture (seconds)
- number of captures (n)
The result is a time-lapse video called IntervalVideo-<date> stored on the desktop. If you also connect an audio signal, it may also be recorded.
-- Ver. 1.1 Time lapse recording (x seconds at beginning of each of n intervals )
-- Ian Parker first worked on 2010-10-04, last worked on 2010-10-05
-- Mac OS X 10.6.4, nearly all functionality derived from QT Player 10
-- can manage basic recording from any Mac enabled USB/Firewire camera
set {today, save_folder} to {current date, (path to desktop as string)}
set dateString to (year of today & "-" & (month of today as number) & "-" & day of today) as string
set alert_message to "Please connect ELPD06 document camera"
tell application "QuickTime Player" to set connected_camera_list to name of every video recording device
if "ELPDC06" is in connected_camera_list then
display dialog "Between capture off time: (seconds)?" default answer 15 buttons {"OK"} default button 1
set capture_interval_off to text returned of result
display dialog "Capture on time: (seconds)?" default answer 1 buttons {"OK"} default button 1
set capture_interval_on to text returned of result
display dialog "Capture intervals (number)?" default answer 4 buttons {"OK"} default button 1
set capture_number to text returned of result
tell application "QuickTime Player"
activate
set recording_document to new movie recording
start recording_document
end tell
delay capture_interval_on + 1
repeat with interval_counter from 2 to capture_number
tell application "QuickTime Player" to pause recording_document
delay capture_interval_off
tell application "QuickTime Player" to resume recording_document
delay capture_interval_on
end repeat
tell application "QuickTime Player" to stop recording_document
tell application "Finder"
try
set name of file (save_folder & "Movie Recording.mov") to "IntervalVideo-" & dateString & ".mov"
update save_folder
end try
end tell
tell application "QuickTime Player" to quit
else -- there's no point continuing so ...
say alert_message
display alert alert_message as warning buttons {"OK"} default button 1
end if
